GRIDs e GRID acesso direto

Desvendando as GRIDs

As grades de informações (GRID) desde o inicio sempre foram uma excelente maneira de exibir informações das tabelas em tela, na HMG no inicio podiamos usar GRID e BROWSE, porém este segundo foi descontinuado, pois o componente GRID passou a desempenhar muito bem a função do BROWSE.

Quem me conhece sabe que não gosto de fazer nada que não funcione muito bem, então de antecipação já aviso a todos que a movimentação do cursor de seleção dentro da GRID não é muito satisfatório, pois é possível ver a atualização dos dados acontecendo, felizmente posso dizer a todos que na HMG4 o problema já foi solucionado, porém ainda estamos usando a HMG3 então tenho este pequeno desagradável problema (muitos vão achar normal, é que eu sou chato mesmo).

As duas formas de usar uma GRID

Existem duas formas de usar uma GRID e você terá que escolher por uma delas dependendo o momento, aviso também que isso fica muito ao critério do programador. Mas enfim a primeira forma de utilizá-la, é abastecendo-a de maneira direta como se fosse uma variável matriz dimensional (array), exatamente através de um comando ADDITEM() você abastece a GRID com informações, ou seja ela exibe o resultado de uma pesquisa simplesmente abstencendo-a com os dados, a segunda maneira é acessando diretamente uma tabela DBF, e assim poder editar, alterar, apagar os dados sem precisar ficar criando códigos extra para isso.

Particularmente não gosto do segundo método, talvez por eu nunca ter gostado de ver meus usuários “olhando” e “mexendo” diretamente nos dados do meu sistema, segundo por não achar profissional esse método, pois imagine níveis de hierarquia do sistema onde determinadas informações são separadas para determinados grupos de usuários, você não tem como separar jogando simplesmente em uma GRID de acesso direto.

O que digo acima tem ressalvas, caso você utilize e faça uma programação com tratamento e separação dos dados, porém se for para fazer isso, então faça usando a GRID como se fosse uma variável array, te garanto que será muito mais profissional o resultado final, pois poderemos fazer filtros, limitar quantidade de dados listados e assim por diante.

Tanto para GRID de acesso direto, como para GRID de acesso indireto, podemos gerar o efeito de mostra listrada, ou seja, linhas que alternam de cores, mas para isso é muito importante que no programa principal (MAIN.PRG) tenhamos a seguinte declaração de variável:

PRIVATE bBackColor:={ || IF( THIS.CELLROWINDEX/2==INT(THIS.CELLROWINDEX/2),;
                         { 234,244,255 },{ 255,255,255 } ) }

Sem esta declaração ocorrerá um erro na sua GRID, e ai fica difícil de continuar o trabalho, não é mesmo?!

Programando a GRID para acesso direto ao DBF

Em primeiro lugar vamos imaginar que possuimos um arquivo DBF aberto com o alias “dbf”, o exemplo abaixo procurei fazer de um jeito que fosse o mais genérico possível, ou seja, você pode colocá-lo em seu formulário (.FMG) e depois apenas alterar as funções que você irá colocar em seu arquivo de código (.PRG), para criar novas grades você faz o mesmo, copia e troca os nomes das funções e altera os dados do DBF. Imaginamos também a seguinte estrutura para o seu arquivo DBF:

CODPRO N 05,00
NOMPRO C 50,00
PREPRO N 15,02
DATPRO D 08,00
SITPRO L 01,00
OBSPRO M 10,00

Então abaixo segue o código para a GRID que será colocado em seu FMG.

DEFINE GRID Grid_Data
        ROW    100
        COL    10
        WIDTH  770
        HEIGHT 440
        ITEMS Nil
        VALUE Nil
        WIDTHS grid_data_widths()
        HEADERS grid_data_headers()
        FONTNAME "Courier New"
        FONTSIZE 9
        TOOLTIP ""
        ONCHANGE main_grid_data_onchange()
        ONGOTFOCUS Nil
        ONLOSTFOCUS Nil
        FONTBOLD .F.
        FONTITALIC .F.
        FONTUNDERLINE .F.
        FONTSTRIKEOUT .F.
        ONDBLCLICK Nil
        ONHEADCLICK Nil
        ONQUERYDATA Nil
        MULTISELECT .F.
        ALLOWEDIT .T.
        VIRTUAL .F.
        DYNAMICBACKCOLOR grid_data_dynamicbackcolor()
        DYNAMICFORECOLOR Nil
        COLUMNWHEN Nil
        COLUMNVALID Nil
        COLUMNCONTROLS grid_data_columncontrols()
        SHOWHEADERS .T.
        CELLNAVIGATION .F.
        NOLINES .F.
        HELPID Nil
        IMAGE Nil
        JUSTIFY grid_data_justify()
        ITEMCOUNT Nil
        BACKCOLOR NIL
        FONTCOLOR NIL
        HEADERIMAGES Nil
        ROWSOURCE "dbf"
        COLUMNFIELDS grid_data_columnfields()
        ALLOWAPPEND .T.
        ALLOWDELETE .T.
        BUFFERED .F.
        DYNAMICDISPLAY Nil
        ONSAVE Nil
        LOCKCOLUMNS 0
    END GRID

Agora basta copiarmos as funções abaixo, para adaptar isso tudo ao seu sistema apenas altere as funções para que fiquem compatíveis com a sua tabela DBF.

FUNCTION grid_data_columnwhen()
LOCAL aColumnWhen

    // { || .T. } PERMITE A EDICAO
    // { || .F. } NAO PERMITE A EDICAO

   aColumnWhem := { { || .F. },;
                    { || .T. },;
                    { || .T. },;
                    { || .T. },;
                    { || .T. },;
                    { || .T. } }

RETURN aColumnWhen

FUNCTION grid_data_columncontrols()
LOCAL aColumnControls

   aColumnControls := { { "TEXTBOX","NUMERIC","99999" },;
                        { "TEXTBOX","CHARACTER" },;
                        { "TEXTBOX","NUMERIC","999999999999.99" },;
                        { "DATEPICKER","UPDOWN" },;
                        { "CHECKBOX",".T.",".F." },;
                        { "EDITBOX" } }

RETURN aColumnControls 

FUNCTION grid_data_columnfields()
LOCAL aColumnFields

   aColumnFields := { "dbf->codpro",;
                     "dbf->nompro",;
                     "dbf->prepro",;
                     "dbf->datpro",;
                     "dbf->sitpro",;
                     "dbf->obspro" }

RETURN aColumnFields

FUNCTION grid_data_headers()
LOCAL aheaders

   aheaders := { "Codigo",;
                 "Nome",;
                 "Preco",;
                 "Entrada",;
                 "Ativo",;
                 "observação" }

RETURN aheaders

FUNCTION grid_data_widths()
LOCAL awidths := {}

   aWidths := { 70,350,120,100,40,50 }

RETURN awidths

FUNCTION grid_data_justify()
LOCAL ajustify := {}

   ajustify := { GRID_JTFY_RIGHT,;
                 GRID_JTFY_LEFT,;
                 GRID_JTFY_RIGHT,;
                 GRID_JTFY_CENTER,;
                 GRID_JTFY_CENTER,;
                 GRID_JTFY_CENTER }

RETURN ajustify

FUNCTION grid_data_DynamicBackColor()
LOCAL aDynamicBackColor := {}

   aDynamicBackColor := { bBackColor,;
                          bBackColor,;
                          bBackColor,;
                          bBackColor,;
                          bBackColor,;
                          bBackColor }

RETURN aDynamicBackColor

Assim termino a primeira parte da explicação do uso da GRID, está primeira parte tratou do acesso direto as informações que estão dentro de uma tabela DBF.

Segue aqui o link com o exemplo:

http://www.mediafire.com/?vhc95nbw9odkwyc

No próximo post falarei sobre o acesso indireto.

Ate+